***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 28, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt 3p0SMCJ28CA-AU 1 2
.param
+vc0 = 1.246e-9	      vc1 = 2.416e-8		vc2 = 1.000e-1      vc3 = 2.406e-10		vc4 = 10.355e-2
+tc1 = 9.165e-4		tc2 = 3.151e-2		tc3 = 2.921e-3		tc4 = 5.451e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1   1 c11 zener
g1 c11   1 value = {irexp(v(c11, 1))}
v1 c11 c12 0
e1 c12 c   value = {rbv(i(v1))}
d2   2 c21 zener
g2 c21   2 value = {irexp(v(c21, 2))}
v2 c21 c22 0
e2 c22   c value = {rbv(i(v2))}
.func rbv(i) {6.939e-2*min(i,0)}
.model zener d
***** flag parameter *****
+level = 1   
***** dc model parameter *****
+ is = 1.000e-14	   n = 1.000		  rs = 1.000e-3		 
+ibv = 1e-3		   nbv =1.000		  bv = 32.75
***** capacitance parameter *****
+cjo = 2.30e-9	   m = 2.532e-1		  vj = 1.117
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.000		 xti = 3	
+tbv1 = 8.46968e-4	 tbv2 = 1.047e-7		 
.ends 3p0SMCJ28CA-AU 
*$
